set term post eps enh color 12 
set out "Hubbard_Heisenberg_NNN_deriv.eps"
set size 0.5,0.5
set multiplot
set samples 1000
set rmargin 1
set lmargin 7

PS=0.8
PS1=0.7
PS2=0.6
set style line 2 lt 2 lc rgb "#00BB00" lw 3 pt 4  ps 0.5
set style line 5 lt 5 lc rgb "#00BBBB" lw 3
set style line 7 lt 1 lc rgb "#FFFF7E" lw 15
set style line 8 lt 1 lc rgb "#00FFFF" lw 15

set xlabel "s" offset 0,0.5
set ylabel "d<S_i {/Symbol \327} S_{i+{/Symbol d}}> / ds" offset 1.2
set key samplen 2 spacing 1.3 bottom
# reverse
set xtics 0.2
set mxtics 2
set ytics 0.2
set mytics 2


set arrow 1 from log(2),-2.05 to log(2),0 nohead lt 4 lc -1 front
#set label 1 "{/Symbol d} = (1,0)" at 0.1,-0.4
#set label 2 "{/Symbol d} = (1,1)" at 0.1,0.3
set label 2 "{/=14{/Symbol d} = NNN}" at screen 0.16,0.44

#set label 3 "{/=9 Weiss MF}" at 0.1,0.96 rotate by -34

set xzeroaxis

set arrow from log(2)/2,-1.8 to log(2)/2,-1.6 lc 3

plot [0:1.05][-2.05:0]\
"Data/DMFT/results_U150mu0_spincorr_deriv.dat" u 1:3 t"DMFT" w lp lt 1 lw 3 pt 6 ps PS1,\
"Data/DQMC_3D/sisj110u15_deriv.dat" u 1:($1>0.2?3*$3:1/0) w lp t"d = 3" lt 3 lw 3 pt 12 ps PS1,\
"< cat Data/DQMC_2D/U12.25L6_beta_s_sisj_deriv.dat | ../bin/printcol 1 3 | ../bin/smooth12" u ($1):($1>0.2?3*$2:1/0) w lp t "d = 2" ls 2,\
"Data/DQMC_1D/DQMC_1d_U867_N16_32_64_deriv.dat" u 1:(3*$3) t"d = 1" w lp lt 4 lw 3 pt 1 ps PS1,\
"< tail +200 Data/Heisenberg/Heisenberg_WeissMF_T_E_s.dat | ../bin/printcol 3 2 | ../bin/deriv12_stable" u 1:(-2*$3) t"" w l lt 1 lw 3 lc -1,\
"Data/Heisenberg/Heisenberg_16x16x16_RTS_deriv.dat" u 1:($1>0.18?12*$3:1/0) t"" w l lt 1 lw 1 lc 3,\
"Data/Heisenberg/Heisenberg_16x16x16_RTS_deriv.dat" u 1:($1>0.27?12*$3:1/0) t"" w l lt 1 lw 4 lc 3,\
"Data/Heisenberg/Heisenberg_Scalettar_12x12_deriv.dat" u 1:($1>0.05?12*$3:1/0) t"" w l lt 1 lw 1 lc 2,\
"Data/Heisenberg/Heisenberg_Scalettar_12x12_deriv.dat" u 1:($1>0.16?12*$3:1/0) t"" w l lt 1 lw 4 lc 2,\
"< cat Data/Heisenberg/corr_xxx_AF_s.dat | ../bin/printcol 10 3 | ../bin/deriv12_stable" u 1:(12*$3) t"" w l lt 1 lw 4 lc 4,\
x<0.273?-2.16*x**0.3333:1/0 t"" lt 1 lw 4 lc 3,\
x<0.164?-2.34*x**0.5:1/0 t"" lt 1 lw 4 lc 2

# cubic Heisenberg fit yields GS NNN correlation 0.856. Literature value: 0.857 - perfect match!
# square Heisenberg fit yields GS NNN correlation 0.812. Literature value: 0.812 - perfect match!

 

